# -*- shell-script -*-
# Copyright (c) 2007 Cisco Systems, Inc.  All rights reserved.

# Startup
AC_INIT([openfoam-selector],
        [m4_normalize(esyscmd([cat VERSION]))],
        [], [openfoam-selector])
AM_INIT_AUTOMAKE([foreign dist-bzip2])

# Setup some directory names and filenames that are common across all
# the scripts
prefix_save=$prefix
if test "NONE" = "$prefix"; then
    prefix=/usr/local
fi

AC_MSG_CHECKING([shell startup file directory])
AC_ARG_WITH([shell-startup-dir],
    AC_HELP_STRING([--with-shell-startup-dir=<dir>],
                   [Directory where shell startup files are installed (default: $pkgdatadir)]))
if test "$with_shell_startup_dir" == ""; then
    OPENFOAM_SELECTOR_SHELL_STARTUP_DIR='$(pkgdatadir)'
else
    OPENFOAM_SELECTOR_SHELL_STARTUP_DIR=$with_shell_startup_dir
fi
AC_SUBST(OPENFOAM_SELECTOR_SHELL_STARTUP_DIR)
AC_MSG_RESULT([$OPENFOAM_SELECTOR_SHELL_STARTUP_DIR])

AC_MSG_CHECKING([repository directory])
localstatedir_save="$localstatedir"
eval localstatedir="$localstatedir"
eval OPENFOAM_SELECTOR_DATADIR="$localstatedir/openfoam-selector/data"
AC_SUBST(OPENFOAM_SELECTOR_DATADIR)
localstatedir="$localstatedir_save"
AC_MSG_RESULT([$OPENFOAM_SELECTOR_DATADIR])

AC_MSG_CHECKING([system configuration directory])
sysconfdir_save="$sysconfdir"
eval sysconfdir="$sysconfdir"
eval OPENFOAM_SELECTOR_SYSCONFDIR="$sysconfdir/sysconfig"
AC_SUBST(OPENFOAM_SELECTOR_SYSCONFDIR)
sysconfdir="$sysconfdir_save"
AC_MSG_RESULT([$OPENFOAM_SELECTOR_SYSCONFDIR])

OPENFOAM_SELECTOR_SYSCONFIG_FILE="openfoam-selector"
OPENFOAM_SELECTOR_HOME_FILE=".openfoam-selector"
AC_SUBST(OPENFOAM_SELECTOR_SYSCONFIG_FILE)
AC_SUBST(OPENFOAM_SELECTOR_HOME_FILE)

prefix=$prefix_save

# Information for the man page
MAN_DATE=`date "+%B %d, %Y"`
AC_SUBST(MAN_DATE)

# Party on
AC_CONFIG_FILES([
    Makefile

    openfoam-selector
    openfoam-selector.sh
    openfoam-selector.csh
])
AC_CONFIG_COMMANDS([tasty], [
for file in openfoam-selector openfoam-selector.sh;
do
  if test -f "$file"; then
     chmod -w $file
     chmod +x $file
  fi
done])
AC_OUTPUT